format PE GUI 4.0
include 'win32a.inc'

; ######################################
; ##    Simple WinInet Downloader     ##
; ##    by Gloomy {gl00my@gmx.net}    ##
; ##         25 Dec 2004              ##
; ######################################

        invoke InternetOpen,downloader_id,0,0,0,0
        test eax,eax
        jnz @F
        mov eax,lpnosession
        call ShowError
        jmp _exit
@@:
        mov [hInt],eax
        invoke InternetOpenUrl,eax,remote_url,0,0,0,0
        test eax,eax
        jnz @F
        mov eax,lpnourl
        call ShowError
        jmp _close_inet
@@:
        mov [hUrl],eax
        invoke CreateFile,local_file,GENERIC_WRITE,FILE_SHARE_READ,NULL,OPEN_ALWAYS,FILE_ATTRIBUTE_NORMAL,NULL
        test eax,eax
        jns @F
        mov eax,lpnoopenfile
        call ShowError
        jmp _close_inet
@@:
        mov [hFile],eax
_read_remote_file:
        invoke InternetReadFile,[hUrl],buff,2000h,dwRWurl
        test eax,eax
        jnz @F
        mov eax,lpnoremotefile
        call ShowError
        jmp _error_read_remote_file
@@:
        cmp [dwRWurl],0
        je @F
        invoke WriteFile,[hFile],buff,[dwRWurl],dwRWfile,0
        jmp _read_remote_file
@@:
        invoke MessageBox,0,lpdownloadok,lpinfo,MB_ICONINFORMATION+MB_TOPMOST
_error_read_remote_file:
        invoke CloseHandle,[hFile]
_close_inet:
        invoke InternetCloseHandle,[hInt]
_exit:
        invoke ExitProcess,0

proc ShowError
        invoke MessageBox,0,eax,0,MB_ICONERROR+MB_TOPMOST
        ret
endp

   buff rb 2000h
   local_file db 'C:\list.gif',0
   remote_url db 'http://www.wasm.ru/forum/files/2103704792__list1.gif',0

   hFile dd 0
   hInt dd 0
   hUrl dd 0

   dwRWfile dd 0
   dwRWurl dd 0

   downloader_id db 'SmplWinIntDwn',0

   lpsetuperror db 'There are errors in settings file!',0Dh,'Please check your settings!',0
   lpnosession db 'Unable to create new remote session!',0
   lpnourl db 'There are no connection with remote host!',0Dh,'Please check is connection alive?',0
   lpnoopenfile db 'Unable to create\open local file!',0Dh,'Please check your settings!',0
   lpnoremotefile db 'Error while reading remote file!',0
   lpdownloadok db 'Download complete!',0Dh,'Enjoy! :)',0
   lpinfo db 'Info',0

data import

library kernel,'KERNEL32.DLL',\
         wininet,'WININET.DLL',\
         user32,'USER32.DLL'

import kernel,\
        ExitProcess,'ExitProcess',\
        CloseHandle,'CloseHandle',\
        CreateFile,'CreateFileA',\
        WriteFile,'WriteFile'

import wininet,\
        InternetOpen,'InternetOpenA',\
        InternetOpenUrl,'InternetOpenUrlA',\
        InternetReadFile,'InternetReadFile',\
        InternetCloseHandle,'InternetCloseHandle'
import user32,\
        MessageBox,'MessageBoxA'
end data